Hi..I'm not sure if this is what you want, it copies the directory name into
a variable (sBuffer). This uses a different dialog than the one you'd expect.
You'll have to modify per your requirements.

Regards,

Tim Hamel

(Sorry for the lengthy code)
Option Explicit

               Private Const BIF_RETURNONLYFSDIRS = 1
               Private Const BIF_DONTGOBELOWDOMAIN = 2
               Private Const MAX_PATH = 260

               Private Declare Function SHBrowseForFolder Lib _
               "shell32" (lpbi As BrowseInfo) As Long

               Private Declare Function SHGetPathFromIDList Lib _
               "shell32" (ByVal pidList As Long, ByVal lpBuffer _
               As String) As Long

               Private Declare Function lstrcat Lib "kernel32" _
               Alias "lstrcatA" (ByVal lpString1 As String, ByVal _
               lpString2 As String) As Long

               Private Type BrowseInfo
                  hWndOwner As Long
                  pIDLRoot As Long
                  pszDisplayName As Long
                  lpszTitle As Long
                  ulFlags As Long
                  lpfnCallback As Long
                  lParam As Long
                  iImage As Long
               End Type

               Private Sub Command1_Click()
               'Opens a Browse Folders Dialog Box that displays the
               'directories in your computer
               Dim lpIDList As Long 'Declare Varibles
               Dim sBuffer As String
               Dim szTitle As String
               Dim tBrowseInfo As BrowseInfo

               szTitle = "Hello World. Click on a directory and " & _
               "it's path will be displayed in a message box"
               'Text to appear in the the gray area under the title bar
               'telling you what to do

               With tBrowseInfo
                  .hWndOwner = Me.hWnd 'Owner Form
                  .lpszTitle = lstrcat(szTitle, "")
                  .ulFlags = BIF_RETURNONLYFSDIRS + BIF_DONTGOBELOWDOMAIN
               End With

               lpIDList = SHBrowseForFolder(tBrowseInfo)

               If (lpIDList) Then
                  sBuffer = Space(MAX_PATH)
                  SHGetPathFromIDList lpIDList, sBuffer
                  sBuffer = Left(sBuffer, InStr(sBuffer, vbNullChar) - 1)
                  MsgBox sBuffer
               End If

               End Sub

In a message dated 3/27/00 12:24:26 PM Pacific Standard Time,
shb7@CORNELL.EDU writes:

> Yeah, that's the impression I got of the open dialog.
>
>  Here's what I am doing: I'm writing a simple program which will
>  periodically copy a bunch of files and directories from several other
>  machines to a "server" for backup purposes. Because the files IN those
>  directories can change, I can't simply select all the files in the dirs,
>  I have to select the dir name. I also want the capability to select
>  individual files for cases where you only want to back up one file from a
>  directory, etc. These selections will go into a text file as
>  path+filename strings. WHen the program needs to do the actual copy, it
>  will open the text file and just go down the list, performing each copy.
>
>  Sean
>
>