Kenny Baby <MCTKEAW@MH1.MCC.AC.UK> wrote:

>I HAVE THE FOLLOWING
>
>
>ROW1    MOVLW 0x04      ;NO OF DATA BYTES TO SEND
>        MOVWF COUNT2    ;PUT INTO COUNT2
>REP     MOVF COUNT2,W   ;W NOW ALSO CONTAINS TABLE POINTER
>        CALL LCDROW1    ;GET DATA FOR LCD DISPLAY
>        MOVWF LCDDATA   ;PUT IN FILE USED BY SENDLCD
>        CALL SENDLCD    ;GO AND PUT IT ON THE LCD DISPLAY
>        DECFSZ COUNT2   ;DEC NO OF INSTRUCTIONS AND TABLE POINTER
>        GOTO REP        ;IF NOT ZERO REPEAT ABOVE
>                        ;ZERO CONTINUE WITH SOMETHING ELSE
>
>LCDROW1 ADDWF PCL,F     ADD OFFSET TO PROGRAM COUNTER
>        RETLW ' '
>        RETLW 'L'
>        RETLW 'O'
>        RETLW 'A'
>        RETLW 'D'


    What you have, Kenny, is code that'll display "DAOL " on the
    display.


>I NEED TO REPEAT THE ABOVE BLOCK AS MANY TIMES AS I HAVE LOOKUP TABLES
>
>IS THERE ANY WAY, OF TURNING IT INTO A UNIVERSAL CALL ROUTINE, I
>COULD PRE LOAD THE COUNT2 FILE BEFORE THE CALL IS MADE, BUT IS THERE
>ANY WAY OF GETTING AROUND THE 'CALL LCDROW1'. THE 'LCDROW1' BEING THE
>ONLY VARIABLE IN THE ROUTINE.


    Don't forget that the "MOVLW 0x04" is another variable for which
    you'll have to account.


>IS THERE A WAY
>.
>.
>.
>.
>.
>.
>.
>.
>.
>.
>I've seen things you people wouldn't believe.
>Attack ships on fire off the sholder of Orion.
>I watched C-beams glitter in the darkness at Tan Hauser Gate.
>All those moments will be lost in time,
>like tears in rain.
>Time to die.
>
>Remember now, watch out for the Fairies......!


    I wish I knew why your signature annoys me so damned much... When I
    figure it out, I'll let you know.

    Anyway, try something like this:

        ADDRESS EQU     [any file register]
        COUNT2  equ     [another one]

        LOOKUP  MOVWF   PCL

        STRING1 DT      STRING2-STRING1+1,"This is String #1"
        STRING2 DT      STRING3-STRING2+1,"String #2"
        STRING3 DT      STRING4-STRING3+1,"You get the idea..."
        STRING4 ....

        DISPLAY MOVWF   ADDRESS
                CALL    LOOKUP
                MOVWF   COUNT2
        LOOP    INCF    ADDRESS
                MOVF    ADDRESS,W
                CALL    LOOKUP
                MOVWF   LCDDATA
                CALL    SENDLCD
                DECFSZ  COUNT2
                GOTO    LOOP

        ....

        MAIN    MOVLW   STRING1     ;DISPLAY STRING #1.
                CALL    DISPLAY     ;

                MOVLW   STRING2     ;DISPLAY STRING #2.
                CALL    DISPLAY     ;

                MOVLW   STRING3     ;DISPLAY STRING #3.
                CALL    DISPLAY     ;

    -Andy

--
Andrew Warren - fastfwd@ix.netcom.com
Fast Forward Engineering, Vista, California